{ config, pkgs, lib, ... }:

let
  nomarchyLib = import ../../lib { inherit lib; };
  
  # Dependencies for theme engine scripts
  themeDeps = with pkgs; [
    coreutils
    gnused
    gnugrep
    findutils
    gawk
    jq
    swww
    libnotify
    gum
    brightnessctl
    playerctl
    pamixer
    bc
  ];

  nomarchy-theme-engine-scripts = pkgs.stdenv.mkDerivation {
    pname = "nomarchy-theme-engine-scripts";
    version = "1.0.0";
    src = ./scripts;

    nativeBuildInputs = [ pkgs.makeWrapper ];

    installPhase = ''
      mkdir -p $out/bin
      cp * $out/bin/

      chmod +x $out/bin/*
      patchShebangs $out/bin
    '';

    postFixup = ''
      deps="${lib.makeBinPath themeDeps}"
      for file in $out/bin/*; do
        if [ -f "$file" ]; then
          wrapProgram "$file" \
            --prefix PATH : "$deps" \
            --set NOMARCHY_PATH "/etc/nixos/nomarchy"
        fi
      done
    '';
  };
in
{
  home.packages = [ nomarchy-theme-engine-scripts ];
}
